Hide Table of Contents

Get Mirror Feature Data Example (VBA)

This example shows how to get a mirror feature's data.

 

'----------------------------------------

'

' Preconditions:

'        (1) Model document is open.

'        (2) Mirror feature is selected.

'

' Postconditions: None

'

'-----------------------------------------

Option Explicit

Sub main()

    Dim swApp                   As SldWorks.SldWorks

    Dim swModel                 As SldWorks.ModelDoc2

    Dim swSelMgr                As SldWorks.SelectionMgr

    Dim swFeat                  As SldWorks.feature

    Dim swMirrorPatt            As SldWorks.MirrorPatternFeatureData

    Dim vFaceArr                As Variant

    Dim vPattArr                As Variant

    Dim swFace                  As SldWorks.face2

    Dim swFeatPatt              As SldWorks.feature

    Dim swEnt                   As SldWorks.Entity

    Dim swPlaneFeat             As SldWorks.feature

    Dim swSelData               As SldWorks.SelectData

    Dim bRet                    As Boolean

    Dim i                       As Long

    

    Set swApp = CreateObject("SldWorks.Application")

    Set swModel = swApp.ActiveDoc

    Set swSelMgr = swModel.SelectionManager

    Set swSelData = swSelMgr.CreateSelectData

    Set swFeat = swSelMgr.GetSelectedObject5(1)

    Set swMirrorPatt = swFeat.GetDefinition

    

    ' Get mirror feature's data

    Debug.Print "File = " & swModel.GetPathName

    Debug.Print "  " & swFeat.Name

    Debug.Print "    GeometryPattern        = " & swMirrorPatt.GeometryPattern

    Debug.Print "    MirrorFaceCount        = " & swMirrorPatt.GetMirrorFaceCount

    Debug.Print "    MirrorPlaneType        = " & swMirrorPatt.GetMirrorPlaneType

    Debug.Print "    PatternFeatureCount    = " & swMirrorPatt.GetPatternFeatureCount

    ' Roll back to get to the faces and features

    bRet = swMirrorPatt.AccessSelections(swModel, Nothing): Debug.Assert bRet

    swModel.ClearSelection2 True

    bRet = False

        

    If 1 = swMirrorPatt.GetMirrorPlaneType Then

        Set swPlaneFeat = swMirrorPatt.Plane

        

        ' Cannot select a reference plane through Entity, so

        ' use Feature

        Debug.Print "    Plane                  = " & swPlaneFeat.Name

        

        bRet = swPlaneFeat.Select2(True, 0): Debug.Assert bRet

    Else

        ' Select face through Entity

        Set swEnt = swMirrorPatt.Plane

        

        bRet = swEnt.Select4(True, swSelData): Debug.Assert bRet

    End If

    Debug.Assert bRet

    If bRet Then Stop

    

    

    vFaceArr = swMirrorPatt.MirrorFaceArray

    If Not IsEmpty(vFaceArr) Then

        swModel.ClearSelection2 True

        bRet = False

        

        For i = 0 To UBound(vFaceArr)

            Set swFace = vFaceArr(i)

            Set swEnt = swFace

            

            bRet = swEnt.Select4(True, swSelData): Debug.Assert bRet

        Next i

        If bRet Then Stop

    End If

    

    

    vPattArr = swMirrorPatt.PatternFeatureArray

    If Not IsEmpty(vPattArr) Then

        swModel.ClearSelection2 True

        bRet = False

        

        For i = 0 To UBound(vPattArr)

            Set swFeatPatt = vPattArr(i)

    

            Debug.Print "    Feature (" & i & ")            = " & swFeatPatt.Name

            

            bRet = swFeatPatt.Select2(True, 0): Debug.Assert bRet

        Next i

        If bRet Then Stop

    End If

    

    

    ' Cancel changes

    swMirrorPatt.ReleaseSelectionAccess

End Sub

'----------------------------------------



Provide feedback on this topic

SOLIDWORKS welcomes your feedback concerning the presentation, accuracy, and thoroughness of the documentation. Use the form below to send your comments and suggestions about this topic directly to our documentation team. The documentation team cannot answer technical support questions. Click here for information about technical support.

* Required

 
*Email:  
Subject:   Feedback on Help Topics
Page:   Get Mirror Feature Data Example (VBA)
*Comment:  
*   I acknowledge I have read and I hereby accept the privacy policy under which my Personal Data will be used by Dassault Systèmes

Print Topic

Select the scope of content to print:



x

We have detected you are using a browser version older than Internet Explorer 7. For optimized display, we suggest upgrading your browser to Internet Explorer 7 or newer.

 Never show this message again
x

Web Help Content Version: API Help (English only) 2010 SP05

To disable Web help from within SOLIDWORKS and use local help instead, click Help > Use SOLIDWORKS Web Help.

To report problems encountered with the Web help interface and search, contact your local support representative. To provide feedback on individual help topics, use the “Feedback on this topic” link on the individual topic page.