Get Fixed Face of Sheet Metal Feature Example (VBA)

This example shows how to find and select the fixed face of a sheet metal part.

'-----------------------------------------

'

' Preconditions: Part document is open and a

'                sheet metal part is selected in

'                the FeatureManager design tree.

'

' Postconditions: Fixed face is found and selected. Then, the

'                 sheet metal part is returned to its original state.

'

'-------------------------------------------

Option Explicit

Sub main()

    Dim swApp                   As SldWorks.SldWorks

    Dim swModel                 As SldWorks.ModelDoc2

    Dim swSelMgr                As SldWorks.SelectionMgr

    Dim swSelData               As SldWorks.SelectData

    Dim swFeat                  As SldWorks.feature

    Dim swSheetMetal            As SldWorks.SheetMetalFeatureData

    Dim swFixedFaceEnt          As SldWorks.Entity

    Dim bRet                    As Boolean

    Set swApp = Application.SldWorks

    Set swModel = swApp.ActiveDoc

    Set swSelMgr = swModel.SelectionManager

    Set swSelData = swSelMgr.CreateSelectData

    Set swFeat = swSelMgr.GetSelectedObject5(1)

    Set swSheetMetal = swFeat.GetDefinition

    ' Roll back the model to get access to fixed face

    bRet = swSheetMetal.AccessSelections(swModel, Nothing)

    Set swFixedFaceEnt = swSheetMetal.FixedReference

    If Not swFixedFaceEnt Is Nothing Then

        Debug.Print "Got fixed face or fixed edge"

        bRet = swFixedFaceEnt.Select4(False, swSelData): Debug.Assert bRet

    Else

        ' Do not have to specify fixed face or fixed edge in user interface,

        ' so NULL is a valid value

        Debug.Print "NULL fixed face or fixed edge"

    End If

    ' Cancel changes and roll back the model

    swSheetMetal.ReleaseSelectionAccess

End Sub