Move Annotations to First Annotation View Example (VBA)

This example shows how to move annotations to the Unassigned Items annotation view.

'----------------------------------------------
' Preconditions:
' 1. Open a part or assembly document.
' 2. Add a note to the *Top annotation view.
' 3. Add a note to the *Front annotation view.
'    NOTES: 
'    * If necessary, create *Top and *Front 
'      annotation views.
'    * If prompted to turn on feature dimensions
'      display, click No.
' 4. Open the Immediate window.
' 5. Run the macro.
'
' Postconditions:
' 1. Prints the names of the annotation views and notes
'    to the Immediate window.
' 2. Moves both notes to the Unassigned Items
'    annotation view.
' 3. Double-click each annotation view in the Annotations
'    folder in the FeatureManager design tree to verify.
'----------------------------------------------

Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swModelExt As SldWorks.ModelDocExtension
Dim swAnnViews As Variant               
Dim annotations As Variant              
Dim annToMove(1) As SldWorks.Annotation  
Dim swAnnView As SldWorks.AnnotationView
Dim swAnn As SldWorks.Annotation
Dim swFeat As SldWorks.Feature
Dim i As Long
Dim j As Long
Dim k As Long
Dim status As Boolean

Sub main()

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    Set swModelExt = swModel.Extension      

    swAnnViews = swModelExt.AnnotationViews    

    'Activate each view
    'Only one view can be active at a time
    For i = 0 To swModelExt.AnnotationViewCount - 1
        Set swAnnView = swAnnViews(i)
        Set swFeat = swAnnView
        Debug.Print "Annotation view name: " & swFeat.Name
        swAnnView.Activate
        'Alternative to activate
        'swAnnView.ActivateAndReorient
    Next
    

    'Print each annotation name and add all annotations to an array
    For i = 0 To swModelExt.AnnotationViewCount - 1
        Set swAnnView = swAnnViews(i)
        swAnnView.Activate
        annotations = swAnnView.annotations
        If Not IsEmpty(annotations) Then
            For j = 0 To UBound(annotations)
                Set swAnn = annotations(j)
                Set annToMove(j) = swAnn
                Debug.Print "Annotation name: " & swAnn.GetName
            Next
        End If
    

        'Move all annotations to first annotation view, Unassigned Items
        If i > 0 Then
            Set swAnnView = swAnnViews(i)
            status = swAnnView.MoveAnnotations(annToMove)
            Debug.Assert status
        End If
    Next

End Sub