Get Dimension Tolerance Example (VBA)
This example shows how to set and get dimension tolerance values.
'---------------------------------------------
' Preconditions:
' 1. Open:
' C:\Program Files\SolidWorks Corp\SolidWorks\samples\tutorial\api\gtolwitnessline.slddrw
' 2. Open the Immediate window.
' 3. Zoom in on a dimension and click it.
' 4. Run the macro.
'
' Postconditions:
' 1. The dimension tolerance for the selected dimension
' is set to basic.
' 2. Minimum and maximum dimension tolerances are set for the
' the selected dimension, and their values printed to the
' the Immediate window.
' 3. The height and scale of the font for the dimension tolerances
' are printed to the Immediate window.
'
' NOTE: Because this part document is used elsewhere, do not
' save any changes when closing it.
'----------------------------------------------
Option Explicit
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swSelMgr As SldWorks.SelectionMgr
Dim swDisplayDimension As SldWorks.DisplayDimension
Dim swDimension As SldWorks.Dimension
Dim swDimensionTolerance As SldWorks.DimensionTolerance
Dim status As Boolean
Dim fontHeight As Double
Dim fontScale As Double
Sub main()
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swSelMgr = swModel.SelectionManager
'Get the selection
Set swDisplayDimension = swSelMgr.GetSelectedObject6(1, 0)
' If selection is not a dimension, then exit
If swSelMgr.GetSelectedObjectType3(1, -1) <> swSelDIMENSIONS Then Exit Sub
' Selection is a dimension, so get the dimension tolerance object
Set swDimension = swDisplayDimension.GetDimension
Set swDimensionTolerance = swDimension.Tolerance
' Set type of Tolerance
swDimensionTolerance.Type = swTolBASIC
' Set dimension tolerance value
status = swDimensionTolerance.SetValues(0.01, 0.015)
Debug.Print ("Minimum dimension tolerance: " & swDimensionTolerance.GetMinValue)
Debug.Print ("Maximum dimension tolerance: " & swDimensionTolerance.GetMaxValue)
' Get some dimension tolerance values
fontHeight = swDimensionTolerance.GetFontHeight
Debug.Print " Height of font = " & fontHeight * 1000#; " mm"
fontScale = swDimensionTolerance.GetFontScale
Debug.Print " Scale of font = " & fontScale
End Sub