Get Dimension of Distance Mate Example (VBA)

This example shows how to get the dimension value of a distance mate in an assembly.

 

NOTE: You can use this sample code to get all the dimension values for any selected feature in the FeatureManager design tree.

 

'-------------------------------------------------------------

'

' Preconditions:

'       (1) Assembly is open.

'       (2) Distance mate feature is selected in the

'           FeatureManager design tree.

'

' Postconditions: None

'

'-------------------------------------------------------------

Option Explicit

Sub ProcessFeature _

( _

    swApp As SldWorks.SldWorks, _

    swModel As SldWorks.ModelDoc2, _

    swFeat As SldWorks.feature _

)

    Dim swDispDim                   As SldWorks.DisplayDimension

    Dim swDim                       As SldWorks.Dimension

    Dim dimValue                    As Variant

    Debug.Print "  " + swFeat.Name

    

    Set swDispDim = swFeat.GetFirstDisplayDimension

    While (Not swDispDim Is Nothing)

        Set swDim = swDispDim.GetDimension

        

        dimValue = swDim.GetSystemValue3(swThisConfiguration, Empty)

        

        Debug.Print "    " + swDim.FullName + " = " & (dimValue(0) * 1000) & " mm "

        

        Set swDispDim = swFeat.GetNextDisplayDimension(swDispDim)

    Wend

End Sub

Sub main()

    Dim swApp                       As SldWorks.SldWorks

    Dim swModel                     As SldWorks.ModelDoc2

    Dim swSelMgr                    As SldWorks.SelectionMgr

    Dim swFeat                      As SldWorks.feature

    Set swApp = Application.SldWorks

    Set swModel = swApp.ActiveDoc

    Set swSelMgr = swModel.SelectionManager

    Set swFeat = swSelMgr.GetSelectedObject5(1)

    

    Debug.Print "File = " & swModel.GetPathName

    

    ProcessFeature swApp, swModel, swFeat

End Sub

'-------------------------------------------------------------