Get Direction of Bendline (VBA)
This example shows how to get the direction of the selected bendline.
'----------------------------------------------------------
' Preconditions:
' 1. Specified model exists.
' 2. Open the Immediate window.
' 3. Run the macro.
'
' Postconditions:
' 1. Specified model is opened.
' 2. Flat-Pattern1 feature is unsuppressed.
' 3. Bendline is selected.
' 4. Direction of bendline is written to the Immediate window.
'
' NOTES: Do not save any changes made to the model when closing
' the model.
'----------------------------------------------------------
Option Explicit
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swModelDocExt As SldWorks.ModelDocExtension
Dim swSelMgr As SldWorks.SelectionMgr
Dim swSketchLine As SldWorks.SketchLine
Dim status As Boolean
Dim errors As Long
Dim warnings As Long
Sub main()
Set swApp = Application.SldWorks
' Open a sheet metal part
Set swModel = swApp.OpenDoc6("C:\Program Files\SolidWorks Corp\SolidWorks\samples\design portfolio\sheet_metal_bracket.sldprt", swDocPART, swOpenDocOptions_Silent, "", errors, warnings)
' Select the flat-pattern feature
Set swModelDocExt = swModel.Extension
status = swModelDocExt.SelectByID2("Flat-Pattern1", "BODYFEATURE", 0, 0, 0, False, 0, Nothing, 0)
' Unsuppress the flat-pattern feature
status = swModel.EditUnsuppress2
swModel.ClearSelection2 True
' Select a bendline
status = swModelDocExt.SelectByID2("Line6@Bend-Lines1", "EXTSKETCHSEGMENT", -0.03274889357189, 0.0721048132238, 0, False, 0, Nothing, 0)
Set swSelMgr = swModel.SelectionManager
Set swSketchLine = swSelMgr.GetSelectedObject6(1, -1)
' Print to the Immediate window the direction of the selected bend line
Debug.Print "Direction of bend line (0= not a bendline; 1 = bendline has up direction; 2 = bendline has down direction): " & swSketchLine.GetBendLineDirection
End Sub