Hide Table of Contents

Get Reference Point Data Example (VBA)

This example shows how to get reference point data.

'----------------------------------------------------------------------------
' Preconditions:
' 1. Open a part, assembly, or drawing document.
' 2. Select the reference point.
'
' Postconditions:
' 1. Features used to create the reference point are selected.
' 2. Press F5 after each feature selection to continue.
' 3. Inspect the Immediate window.
'----------------------------------------------------------------------------

Option Explicit

Sub main()

    Dim swApp                       As SldWorks.SldWorks
    Dim swModel                     As SldWorks.ModelDoc2
    Dim swSelMgr                    As SldWorks.SelectionMgr
    Dim swFeat                      As SldWorks.Feature
    Dim swRefPt                     As SldWorks.RefPoint
    Dim swRefPtData                 As SldWorks.RefPointFeatureData
    Dim swMathPt                    As SldWorks.MathPoint
    Dim vEntArr                     As Variant
    Dim vEnt                        As Variant
    Dim swEnt                       As SldWorks.Entity
    Dim swSkPt                      As SldWorks.SketchPoint
    Dim swSkSeg                     As SldWorks.SketchSegment
    Dim bRet                        As Boolean

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    Set swSelMgr = swModel.SelectionManager
    Set swFeat = swSelMgr.GetSelectedObject6(1, -1)
    Set swRefPt = swFeat.GetSpecificFeature2
    Set swRefPtData = swFeat.GetDefinition
    Set swMathPt = swRefPt.GetRefPoint

    Debug.Print "File = " & swModel.GetPathName
    Debug.Print "  " & swFeat.Name
    Debug.Print "    Pt = (" & swMathPt.ArrayData(0) * 1000# & ", " & swMathPt.ArrayData(1) * 1000# & ", " & swMathPt.ArrayData(2) * 1000# & ") mm"
    Debug.Print "    AlongCurveOption   = " & swRefPtData.AlongCurveOption
    Debug.Print "    Distance           = " & swRefPtData.Distance * 1000# & " mm"
    Debug.Print "    Type               = " & swRefPtData.Type

    bRet = swRefPtData.AccessSelections(swModel, Nothing)
    vEntArr = swRefPtData.Selections

    For Each vEnt In vEntArr
        If Not Nothing Is vEnt Then
            If TypeOf vEnt Is SldWorks.Entity Then
                Set swEnt = vEnt
                bRet = swEnt.Select4(True, Nothing)
                Debug.Print "Entity used to create reference point selected."
                Stop
            ElseIf TypeOf vEnt Is SldWorks.SketchPoint Then
                Set swSkPt = vEnt
                bRet = swSkPt.Select4(True, Nothing)
                Debug.Print "SketchPoint used to create reference point selected."
                Stop
            ElseIf TypeOf vEnt Is SldWorks.SketchSegment Then
                Set swSkSeg = vEnt
                bRet = swSkSeg.Select4(True, Nothing)
                Debug.Print "SketchSegment used to create reference point selected."
                Stop
            Else
            End If
        End If
    Next

    swRefPtData.ReleaseSelectionAccess

End Sub

 



Provide feedback on this topic

SOLIDWORKS welcomes your feedback concerning the presentation, accuracy, and thoroughness of the documentation. Use the form below to send your comments and suggestions about this topic directly to our documentation team. The documentation team cannot answer technical support questions. Click here for information about technical support.

* Required

 
*Email:  
Subject:   Feedback on Help Topics
Page:   Get Reference Point Data Example (VBA)
*Comment:  
*   I acknowledge I have read and I hereby accept the privacy policy under which my Personal Data will be used by Dassault Systèmes

Print Topic

Select the scope of content to print:




x

We have detected you are using a browser version older than Internet Explorer 7. For optimized display, we suggest upgrading your browser to Internet Explorer 7 or newer.

 Never show this message again
x

Web Help Content Version: API Help (English only) 2014 SP05

To disable Web help from within SOLIDWORKS and use local help instead, click Help > Use SOLIDWORKS Web Help.

To report problems encountered with the Web help interface and search, contact your local support representative. To provide feedback on individual help topics, use the “Feedback on this topic” link on the individual topic page.