Hide Table of Contents

Create Casting Costing Analysis Example (VBA)

This example shows how to create a casting Costing analysis of a part.

'------------------------------------------------
' Preconditions:
' 1. Specified part to open exists.
' 2. Add a reference to SldCostingAPI nnnn Type Library.
' 3. Open the Immediate window.
' 4. Run the macro.
'
' Postconditions:
' 1. Opens the specified part.
' 2. Gets the CostingManager.
' 3. Gets the Costing part.
' 4. Sets the Costing manufacturing method
'    to casting and gets the Costing body.
' 5. Gets the common Costing analysis and the
'    casting Costing analysis.
' 6. Gets the material classes from the Costing template
'    and sets the material class.
' 7. Gets the material names from the Costing template
'    and sets the material for the material class.
' 8. Sets and gets casting Costing analysis
'    parameters.
' 9. Gets the total manufacturing cost.
'10. Examine the Immediate window to see the
'    results of steps 6 through 9.
'
' NOTE: Because the part is used elsewhere, do
' not save changes when closing it.
'-------------------------------------------------
Option Explicit
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swModelDocExt As SldWorks.ModelDocExtension
Dim swcCostMgr As SldCostingAPI.CostManager
Dim swcCostPart As SldCostingAPI.CostPart
Dim swcCostBody As SldCostingAPI.CostBody
Dim swcCostAnalysis As SldCostingAPI.CostAnalysis
Dim swcCastingAnalysis As SldCostingAPI.CostAnalysisCasting
Dim fileName As String
Dim errors As Long
Dim warnings As Long
Dim totalCost As Double
Dim templateName As String
Dim materialClassCount As Long
Dim materialClasses As Variant
Dim materialCount As Long
Dim materials As Variant
Dim i As Long
Sub main()
    Set swApp = Application.SldWorks    
    'Open the specified part
    fileName = "C:\Program Files\SolidWorks Corp\SolidWorks\samples\tutorial\api\clamp1.sldprt"
    Set swModel = swApp.OpenDoc6(fileName, swDocumentTypes_e.swDocPART, swOpenDocOptions_e.swOpenDocOptions_Silent, "", errors, warnings)
    Set swModelDocExt = swModel.Extension    
    'Get CostingManager
    Set swcCostMgr = swModelDocExt.GetCostingManager
    If swcCostMgr Is Nothing Then
        Debug.Print "CostingManager is nothing."
        Exit Sub
    End If    
    'Get Costing part
    Set swcCostPart = swcCostMgr.CostingModel
    If swcCostPart Is Nothing Then
        Debug.Print "Costing part is nothing."
        Exit Sub
    End If    
    'Set the Costing manufacturing method
    'to casting and get the Costing body
    Set swcCostBody = swcCostPart.SetCostingMethod("", swcMethodType_e.swcMethodType_Casting)
    If swcCostBody Is Nothing Then
        Debug.Print "Costing body is nothing."
        Exit Sub
    End If    
    Debug.Print ("Casting Costing analysis")
    'Get the common Costing analysis
    Set swcCostAnalysis = swcCostBody.GetCostAnalysis
    If swcCostAnalysis Is Nothing Then
        Debug.Print "Failed to activate Costing analysis."
        Exit Sub
    End If    
    'Get the Casting Costing analysis
    Set swcCastingAnalysis = swcCostAnalysis.GetSpecificAnalysis
    If swcCastingAnalysis Is Nothing Then
        Debug.Print "Casting Costing analysis is nothing."
        Exit Sub
    End If    
    'Get the material classes from the Costing template
    materialClassCount = swcCastingAnalysis.GetMaterialClassesCount
    If materialClassCount = 0 Then
        Debug.Print ("No material classes for this casting Costing analysis.")
        Exit Sub
    End If    
    materialClasses = swcCastingAnalysis.GetMaterialClasses
    Debug.Print ("  Valid material classes for this casting Costing Analysis: ")
    For i = 0 To materialClassCount - 1
        Debug.Print ("    " & materialClasses(i))
    Next i    
    'Set the material class
    swcCastingAnalysis.CurrentMaterialClass = materialClasses(0)
    Debug.Print ("  Name of the material class for this casting Costing analysis: " & materialClasses(0))    
    'Get the material names from the Costing template
    templateName = swcCostAnalysis.CostingTemplateName
    Debug.Print ("  Costing template path and file name: " & templateName)
    materialCount = swcCastingAnalysis.GetMaterialCount(materialClasses(0))
    If materialCount = 0 Then
        Debug.Print "No materials for this casting Costing Analysis."
        Exit Sub
    End If    
    Debug.Print "  Number of materials: " & materialCount
    materials = swcCastingAnalysis.GetMaterials(materialClasses(0))
    Debug.Print ("  Valid materials for this casting Costing Analysis: ")
    For i = 0 To materialCount - 1
        Debug.Print ("    " & materials(i))
    Next i    
    'Set the material
    swcCastingAnalysis.CurrentMaterial = materials(0)
    Debug.Print ("  Name of material for " & materialClasses(0) & " for this casting Costing analysis: " & materials(0))    
    'Set and get casting Costing analysis parameters
    swcCastingAnalysis.PercentWasteMaterial = 20
    swcCastingAnalysis.MoldCost = swcCastingAnalysis.MoldCost / 1500
    Debug.Print ("  Casting Costing analysis parameters:")
    Debug.Print ("    Waste percentage: " & swcCastingAnalysis.PercentWasteMaterial & "%")
    Debug.Print ("    Mold cost: $" & swcCastingAnalysis.MoldCost)
    Debug.Print ("    Casting process cycle time: " & swcCastingAnalysis.CycleTime * 3600 & " in seconds")
    'Reset the shop rate to the default
    swcCastingAnalysis.ResetShopRate
    swcCastingAnalysis.ShopRateApplied = True
    Debug.Print ("    Default shop rate applied: " & swcCastingAnalysis.ShopRateApplied)
    Debug.Print ("    Default shop rate: $" & swcCastingAnalysis.shoprate)
    totalCost = swcCostAnalysis.GetTotalCostToManufacture
    Debug.Print ("Total casting cost to manufacture: $" & totalCost)    
End Sub


Provide feedback on this topic

SOLIDWORKS welcomes your feedback concerning the presentation, accuracy, and thoroughness of the documentation. Use the form below to send your comments and suggestions about this topic directly to our documentation team. The documentation team cannot answer technical support questions. Click here for information about technical support.

* Required

 
*Email:  
Subject:   Feedback on Help Topics
Page:   Create Casting Costing Analysis Example (VBA)
*Comment:  
*   I acknowledge I have read and I hereby accept the privacy policy under which my Personal Data will be used by Dassault Systèmes

Print Topic

Select the scope of content to print:



x

We have detected you are using a browser version older than Internet Explorer 7. For optimized display, we suggest upgrading your browser to Internet Explorer 7 or newer.

 Never show this message again
x

Web Help Content Version: API Help (English only) 2015 SP05

To disable Web help from within SOLIDWORKS and use local help instead, click Help > Use SOLIDWORKS Web Help.

To report problems encountered with the Web help interface and search, contact your local support representative. To provide feedback on individual help topics, use the “Feedback on this topic” link on the individual topic page.