Traverse Files and Folders in Vault Example (VB.NET)

This example shows how to recursively traverse all of the folders and files in a vault. The paths and the names of any files checked out are printed to the Immediate window.

NOTE: If using the .NET Framework 4.0 primary interop assembly provided with SOLIDWORKS PDM Professional, see Using .NET Framework 4.0 in Stand-alone Applications.

'----------------------------------------------------------------------------
' Preconditions:
'  1. Start Microsoft Visual Studio 2010 or later.
'  2. Click File > New > Project > Visual Basic > Windows Forms Application.
'  3. Type TraverseFilesFolders in Name.
'  4. Click Browse and navigate to the folder where to create the project.
'  5. Click OK. 
'  6. Replace the code in Form1.vb with this code.
'  7. Replace the code in Form1.Designer.vb with this code.
'  8. If using Microsoft Visual Studio 2012 and .NET Framework 4.5, ensure
'     that the Prefer 32-bit check box is cleared (right-click the project
'     name in the Solution Explorer and click Properties. On the Compile tab,
'     if Target CPU is set to AnyCPU, ensure that Prefer 32-bit is cleared.)
'  9. Add EPDM.Interop.epdm.dll as a reference (right-click the project
'     name in the Solution Explorer, click Add Reference, click Browse, 
'     navigate to the top folder of your SOLIDWORKS PDM Professional installation, 
'     locate and select EPDM.Interop.epdm.dll).
' 10. Right-click EPDM.Interop.epdm in References, click Properties, and set 
'     Embed Interop Types to False to handle methods that pass arrays of 
'     structures.
' 11. Set focus in the Form1.vb code window.
' 12. Open the Immediate window.
' 13. Click Debug > Start Debugging or press F5.
'
' Postconditions: 
'  1. Displays a Traverse Folders and Files dialog.
'  2. Select a vault.
'  3. Click the Log in and display file information button.
'  4. Displays a message box with the detailed contents of the current user's
'     log.
'  5. Click OK.
'  6. Displays a message box with the vault type.
'  7. Click OK.
'  8. Examine the Immediate window for any checked-out files.
'  9. Close the dialog.
'---------------------------------------------------------------------------- 

'Form1.vb
 
 

Imports EPDM.Interop.epdm
 
Public Class TraverseFilesFolders
 
    Private Sub TraverseFilesFolders_Load( _
      ByVal sender As System.Object, _
      ByVal e As System.EventArgs) _
      Handles MyBase.Load
 
        Try
            Dim vault As IEdmVault16 = New EdmVault5
            Dim Views() As EdmViewInfo = Nothing
           
            vault.GetVaultViews(Views, False)
            VaultsComboBox.Items.Clear()
            For Each View As EdmViewInfo In Views
                VaultsComboBox.Items.Add(View.mbsVaultName)
            Next
            If VaultsComboBox.Items.Count > 0 Then
                VaultsComboBox.Text = VaultsComboBox.Items(0)
            End If
 
        Catch ex As Runtime.InteropServices.COMException
            MessageBox.Show("HRESULT = 0x" + _
              ex.ErrorCode.ToString("X") + vbCrLf + _
              ex.Message)
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
    End Sub
 
    Private Sub TraverseFoldersButton_Click( _
      ByVal sender As System.Object, _
      ByVal e As System.EventArgs) _
      Handles TraverseFoldersButton.Click
 
        Try
            'Declare and create an instance of IEdmVault5 object
            Dim vault As IEdmVault16 = New EdmVault5()
 
            'Log into selected vault as the current user
            vault.LoginAuto(VaultsComboBox.Text, _
              Me.Handle.ToInt32())
 
            Dim log As String = Nothing
            vault.GetClientLog(log)
           
            MessageBox.Show("Client log: " + log)
            
            MessageBox.Show("Vault type: " & vault.GetVaultType().ToString())
 
            Debug.Print(vbCrLf + "Checked out files:" + vbCrLf)
            TraverseFolder(vault.RootFolder)
 
        Catch ex As Runtime.InteropServices.COMException
            MessageBox.Show("HRESULT = 0x" + _
              ex.ErrorCode.ToString("X") + vbCrLf + _
              ex.Message)
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
    End Sub
 
    Private Sub TraverseFolder( _
      ByVal CurFolder As IEdmFolder5)
 
        Try
            'Enumerate the files in the folder
            Dim FilePos As IEdmPos5
            FilePos = CurFolder.GetFirstFilePosition
            Dim file As IEdmFile5
            While Not FilePos.IsNull
                file = CurFolder.GetNextFile(FilePos)
                'Get its checked out status
                If file.IsLocked Then
                    Debug.Print(file.LockPath)
                End If
            End While
 
            'Enumerate the subfolders in the folder
            Dim FolderPos As IEdmPos5
            FolderPos = CurFolder.GetFirstSubFolderPosition
            While Not FolderPos.IsNull
                Dim SubFolder As IEdmFolder5
                SubFolder = CurFolder.GetNextSubFolder _
                  (FolderPos)
                TraverseFolder(SubFolder)
            End While
 
        Catch ex As Runtime.InteropServices.COMException
            MessageBox.Show("HRESULT = 0x" + _
              ex.ErrorCode.ToString("X") + vbCrLf + _
              ex.Message)
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
    End Sub
 
 
End Class

Back to top