Hide Table of Contents

Create Local Sketch-driven Pattern Example (VBA)

This example shows how to create a local sketch-driven pattern feature.

' Preconditions:
' 1. Verify that the specified assembly document to open exists.
' 2. Open the Immediate window.
' Postconditions:
' 1. Opens the assembly document.
' 2. Creates a sketch for the local sketch-driven
'    pattern feature.
' 3. Selects an assembly component and the just-created
'    sketch for the local sketch-driven pattern feature.
' 4. Creates the local sketch-driven pattern feature.
' 5. Gets values and settings of the local sketch-driven 
'    pattern feature.
' 6. Examine the Immediate window and graphics area.
' NOTE: Because this assembly is used elsewhere, do not save changes.
Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModel As ModelDoc2
Dim swSketchMgr As SldWorks.SketchManager
Dim swSketchPoint As SldWorks.SketchPoint
Dim swModelDocExt As SldWorks.ModelDocExtension
Dim swFeatMgr As FeatureManager
Dim swFeat As Feature
Dim swLocalSketchPatternFeat As SldWorks.LocalSketchPatternFeatureData
Dim fileName As String
Dim status As Boolean
Dim errors As Long
Dim warnings As Long
Sub main()
    Set swApp = Application.SldWorks
    'Open assembly document
    fileName = "C:\Users\Public\Documents\SOLIDWORKS\SOLIDWORKS 2018\samples\tutorial\api\assem1.sldasm"
    Set swModel = swApp.OpenDoc6(fileName, swDocumentTypes_e.swDocASSEMBLY, swOpenDocOptions_e.swOpenDocOptions_Silent, "", errors, warnings)
    'Create sketch
    Set swSketchMgr = swModel.SketchManager
    swSketchMgr.InsertSketch True
    Set swSketchPoint = swSketchMgr.CreatePoint(0.025, -0.05, 0#)
    Set swSketchPoint = swSketchMgr.CreatePoint(0.05, -0.075, 0#)
    Set swSketchPoint = swSketchMgr.CreatePoint(0.1, -0.05, 0#)
    swSketchMgr.InsertSketch True 

    'Select a component and the just-created sketch
    'for the local sketch-driven pattern feature
    Set swModelDocExt = swModel.Extension
    status = swModelDocExt.SelectByID2("TestPart1-1@assem1", "COMPONENT", 0, 0, 0, False, 1, Nothing, 0)
    status = swModelDocExt.SelectByID2("Sketch1", "SKETCH", 0, 0, 0, True, 16, Nothing, 0)    
    'Create local sketch-driven pattern feature
    Set swFeatMgr = swModel.FeatureManager
    Set swFeat = swFeatMgr.FeatureLocalSketchDrivenPattern(swLocalSketchPatternReferencePoint_e.swLocalSketchPatternComponentOrigin)
    'Get local sketch-driven pattern feature data
    Set swLocalSketchPatternFeat = swFeat.GetDefinition
    Debug.Print "Local sketch-driven pattern properties: "
    Debug.Print "  Number of components: " & swLocalSketchPatternFeat.GetPatternComponentCount
    Debug.Print "  Number of items skipped: " & swLocalSketchPatternFeat.GetSkippedItemCount
    Debug.Print "  Type of reference point: " & swLocalSketchPatternFeat.ReferencePoint
    Debug.Print "  Is reference point a closed curve, sketch point, vertex, or default value: " & swLocalSketchPatternFeat.GetReferencePointType
End Sub


Provide feedback on this topic

SOLIDWORKS welcomes your feedback concerning the presentation, accuracy, and thoroughness of the documentation. Use the form below to send your comments and suggestions about this topic directly to our documentation team. The documentation team cannot answer technical support questions. Click here for information about technical support.

* Required

Subject:   Feedback on Help Topics
Page:   Create Local Sketch-driven Pattern Example (VBA)
*   I acknowledge I have read and I hereby accept the privacy policy under which my Personal Data will be used by Dassault Systèmes

Print Topic

Select the scope of content to print:


We have detected you are using a browser version older than Internet Explorer 7. For optimized display, we suggest upgrading your browser to Internet Explorer 7 or newer.

 Never show this message again

Web Help Content Version: API Help (English only) 2018 SP05

To disable Web help from within SOLIDWORKS and use local help instead, click Help > Use SOLIDWORKS Web Help.

To report problems encountered with the Web help interface and search, contact your local support representative. To provide feedback on individual help topics, use the “Feedback on this topic” link on the individual topic page.