Hide Table of Contents

Get P-Spline Parameterization Data Example (VBA)

This example shows how to get P-spline parameter data for a selected spline or curve.

' Preconditions:
' 1. Open public_documents\samples\tutorial\molds\telephone.sldprt.
' 2. Select a curved edge of Shell1 in the graphics area.
' 3. Open the Immediate Window.
' Postconditions:
' 1. Gets the P-spline parameter data for the selected curved edge.
' 2. Inspect the Immediate window.

Option Explicit
Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim Part As SldWorks.ModelDoc2

    Set swApp = CreateObject("SldWorks.Application")
    Set Part = swApp.ActiveDoc

    Dim swSelectMgr As Sldworks.SelectionMgr
    Set swSelectMgr = Part.SelectionManager

    Dim swSketchSeg As SldWorks.Edge
    Set swSketchSeg = swSelectMgr.GetSelectedObject6(1, -1)

    Dim swCurveIn As SldWorks.Curve
    Dim swSplineParaData As SldWorks.SplineParamData
    Dim varCtrlPoints As Variant
    Dim varKnotPoints As Variant
    Dim boolStatus As Boolean
    Dim i As Long

    Set swCurveIn = swSketchSeg.GetCurve
    Set swSplineParaData = swCurveIn.GetPCurveParams2

    Debug.Print "P-spline"
    Debug.Print ""
    Debug.Print "The dimension is: " & swSplineParaData.Dimension
    Debug.Print "The order is: " & swSplineParaData.Order
    Debug.Print "The periodicity is: " & swSplineParaData.Periodic
    Debug.Print "The knot count is: " & swSplineParaData.KnotPointsCount
    Debug.Print "Knots: "
    boolStatus = swSplineParaData.GetKnotPoints(varKnotPoints)
    For i = 0 To UBound(varKnotPoints)
        Debug.Print varKnotPoints(i)

    Next i
    Debug.Print "The segment count is: " & swSplineParaData.SegmentCount
    boolStatus = swSplineParaData.GetSegments(varCtrlPoints)
    Debug.Print (swSplineParaData.SegmentCount * swSplineParaData.Dimension * swSplineParaData.Order) & " Coefficients: "
    For i = 0 To UBound(varCtrlPoints)
        Debug.Print varCtrlPoints(i)

    Next i

    Debug.Print ""

    Debug.Print "COLORREF of spline: " & swSplineParaData.Color
    Debug.Print "Layer of spline: " & swSplineParaData.Layer
    Debug.Print "Style overrides as defined in swLayerOverride_e: " & swSplineParaData.LayerOverride
    Debug.Print "Line style as defined in swLineStyles_e:: " & swSplineParaData.LineStyle
    Debug.Print "Line weight at defined in swLineWeights_e: " & swSplineParaData.LineWidth

End Sub

Provide feedback on this topic

SOLIDWORKS welcomes your feedback concerning the presentation, accuracy, and thoroughness of the documentation. Use the form below to send your comments and suggestions about this topic directly to our documentation team. The documentation team cannot answer technical support questions. Click here for information about technical support.

* Required

Subject:   Feedback on Help Topics
Page:   Get P-Spline Parameterization Data Example (VBA)
*   I acknowledge I have read and I hereby accept the privacy policy under which my Personal Data will be used by Dassault Systèmes

Print Topic

Select the scope of content to print:


We have detected you are using a browser version older than Internet Explorer 7. For optimized display, we suggest upgrading your browser to Internet Explorer 7 or newer.

 Never show this message again

Web Help Content Version: API Help (English only) 2018 SP05

To disable Web help from within SOLIDWORKS and use local help instead, click Help > Use SOLIDWORKS Web Help.

To report problems encountered with the Web help interface and search, contact your local support representative. To provide feedback on individual help topics, use the “Feedback on this topic” link on the individual topic page.