Hide Table of Contents

Switch Documents (VBA)

This example shows how to switch documents by opening documents in their own and client model windows.

'----------------------------------------------
' Preconditions:
' 1. Verify that the specified documents to open exist.
' 2. Open the Immediate window.
'
' Postconditions:
' 1. Opens the specified documents in their own 
'    and client model windows.
' 2. Click Window on the main menu to see a list of the
'    open documents.
' 3. Press F5 to continue.
' 4. Closes all open documents.
' 5. Examine the Immediate window.
'----------------------------------------------
Option Explicit
Dim swApp As SldWorks.SldWorks
Dim swModelDoc As SldWorks.ModelDoc2
Dim swFrame As SldWorks.Frame
Dim swModelWindow As SldWorks.ModelWindow
Dim modelWindows As Variant
Dim obj As Variant
Dim errors As Long
Dim warnings As Long
Dim HWnd As Long
Dim fileName As String
Dim strFolder As String
Sub main()
    Set swApp = Application.SldWorks
    'Open the specified documents in their own windows
    fileName = "C:\Users\Public\Documents\SOLIDWORKS\SOLIDWORKS 2018\samples\tutorial\assemblymates\knee.sldprt"
    Set swModelDoc = swApp.OpenDoc6(fileName, swDocumentTypes_e.swDocPART, swOpenDocOptions_e.swOpenDocOptions_Silent, "", errors, warnings)
    'Open client model window containing the active document
    swApp.CreateNewWindow
    fileName = "C:\Users\Public\Documents\SOLIDWORKS\SOLIDWORKS 2018\samples\tutorial\assemblymates\bracket.sldprt"
    Set swModelDoc = swApp.OpenDoc6(fileName, swDocumentTypes_e.swDocPART, swOpenDocOptions_e.swOpenDocOptions_Silent, "", errors, warnings)
    'Open client model window containing the active document
    swApp.CreateNewWindow
    fileName = "C:\Users\Public\Documents\SOLIDWORKS\SOLIDWORKS 2018\samples\tutorial\assemblymates\clamp.sldprt"
    Set swModelDoc = swApp.OpenDoc6(fileName, swDocumentTypes_e.swDocPART, swOpenDocOptions_e.swOpenDocOptions_Silent, "", errors, warnings)
    'Open client model window containing the active document
    swApp.CreateNewWindow
    Set swFrame = swApp.Frame
    modelWindows = swFrame.modelWindows
    Debug.Print "Open documents in their own windows:"
    For Each obj In modelWindows
        Set swModelWindow = obj
        'Get the model document in this model window
        Set swModelDoc = swModelWindow.ModelDoc
        'Rebuild the document
        swModelDoc.EditRebuild3
        Set swModelDoc = Nothing
        'Show the model window
        Debug.Print ""
        swFrame.ShowModelWindow swModelWindow
        'Get and print the model window handle
        HWnd = swModelWindow.HWnd
        Debug.Print ("  Model window handle: " & HWnd)
        'Get and print the model title as it is seen in the model window's title bar
        Debug.Print ("  Model title as it seen in the model's window's title bar: " & swModelWindow.Title)
    Next obj    
    Stop
    'Click Window on the main menu to see a list of the
    'open documents in their own windows
    'Press F5 to continue
    strFolder = ""
    'Specify true to close all documents, specify false to close
    'only the documents not modified
    swApp.CloseAllDocuments True
End Sub


Provide feedback on this topic

SOLIDWORKS welcomes your feedback concerning the presentation, accuracy, and thoroughness of the documentation. Use the form below to send your comments and suggestions about this topic directly to our documentation team. The documentation team cannot answer technical support questions. Click here for information about technical support.

* Required

 
*Email:  
Subject:   Feedback on Help Topics
Page:   Switch Documents Example (VBA)
*Comment:  
*   I acknowledge I have read and I hereby accept the privacy policy under which my Personal Data will be used by Dassault Systèmes

Print Topic

Select the scope of content to print:



x

We have detected you are using a browser version older than Internet Explorer 7. For optimized display, we suggest upgrading your browser to Internet Explorer 7 or newer.

 Never show this message again
x

Web Help Content Version: API Help (English only) 2018 SP05

To disable Web help from within SOLIDWORKS and use local help instead, click Help > Use SOLIDWORKS Web Help.

To report problems encountered with the Web help interface and search, contact your local support representative. To provide feedback on individual help topics, use the “Feedback on this topic” link on the individual topic page.