Create Surface Knit Feature Example (VBA)

This example shows how to create a Surface-Knit feature and get its properties.

'-------------------------------------------

' Preconditions: Part document containing two surfaces is open.

'

' Postconditions:

' A Surface-Knit feature is created using the two selected surfaces.

'--------------------------------------------

Option Explicit

Dim swApp As SldWorks.SldWorks

Dim swModel As SldWorks.ModelDoc2

Dim swModelDocExt As SldWorks.ModelDocExtension

Dim swFeatureMgr As SldWorks.FeatureManager

Dim swFeature As SldWorks.Feature

Dim swSurfaceKnitFeature As SldWorks.SurfaceKnitFeatureData

Dim boolstatus As Boolean

Dim longstatus As Long

Sub main()

Set swApp = Application.SldWorks

' Specify the name of your part document

swApp.ActivateDoc2 "SurfaceKnitPartDocument.SLDPRT", False, longstatus

Set swModel = swApp.ActiveDoc

Set swModelDocExt = swModel.Extension

Set swFeatureMgr = swModel.FeatureManager

' Specify your surface selections

boolstatus = swModelDocExt.SelectByID2("Verrundung2", "SURFACEBODY", -0.01350648199224, -0.001914137629626, 0.01055295249466, False, 1, Nothing, 0)

boolstatus = swModelDocExt.SelectByID2("Verrundung1", "SURFACEBODY", -0.0125503446005, -0.002125678282823, -0.007630408959756, True, 1, Nothing, 0)

' Create and get the Surface-Knit feature

Set swFeature = swFeatureMgr.InsertSewRefSurface(True, False, False, 3.001639406912E-05, 0.0001)

Set swSurfaceKnitFeature = swFeature.GetDefinition

' List some of the Knit-Surface feature's properties

' in the Immediate Window

Debug.Print "Knit-surface feature: "

Debug.Print "  Knit tolerance: " & swSurfaceKnitFeature.KnitTolerance * 1000 & " mm"

Debug.Print "  Maximum value for gap range: " & swSurfaceKnitFeature.MaxValueForGapRange * 1000 & " mm"

Debug.Print "  Minimum value for gap range: " & swSurfaceKnitFeature.MinValueForGapRange * 1000 & " mm"

Debug.Print "  Use gap filters? " & swSurfaceKnitFeature.UseGapFilters

Debug.Print "  Use merge entities? " & swSurfaceKnitFeature.UseMergeEntities

Debug.Print "  Try to form solid? " & swSurfaceKnitFeature.UseTryToFormSolid

End Sub