Save Configuration Data Example (VBA)

This example shows how to mark each configuration in a multi-configuration model as needing to be rebuilt and how to save its configuration data, including preview bitmaps, every time you save the model document.

'------------------------------------------------------------
' Preconditions: Specified file to open exists.
'
' Postconditions: Each configuration in the model:
' * is activated.
' * has its Add Rebuild/Save Mark set to true, if it is false.
' * has its preview bitmap saved to disk.
'
' NOTES: 
' * In SolidWorks 2013 and later, to mark each configuration
'   of a multi-configuration model as needing to be rebuilt 
'   and to save its configuration data every time you save
'   the document:
'   1. Activate each configuration and set
'      IConfiguration::AddRebuildSaveMark to true.
'   2. Save the model.
'
' * Because this model is used elsewhere, do not
'   save any changes when closing it.
'------------------------------------------------------------

Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swConfig As SldWorks.Configuration
Dim swConfMgr As SldWorks.ConfigurationManager
Dim configNameArr As Variant
Dim configName As Variant
Dim fileName As String
Dim bitmapName As String
Dim bitmapPathName As String
Dim status As Boolean
Dim errors As Long, warnings As Long

Sub main()

Set swApp = Application.SldWorks
fileName = "C:\Program Files\SolidWorks Corp\SolidWorks\samples\tutorial\api\multiconfig-part-2.sldprt"
Set swModel = swApp.OpenDoc6(fileName, swDocPART, swOpenDocOptions_Silent, "", errors, warnings)
Set swConfMgr = swModel.ConfigurationManager
configNameArr = swModel.GetConfigurationNames

Debug.Print "Checking each configuration's Add Rebuild/Save Mark setting after opening the model document:"

For Each configName In configNameArr
    Set swConfig = swModel.GetConfigurationByName(configName)
    status = swModel.ShowConfiguration2(configName)
    Debug.Print ("   " & configName & "'s" & " Add Rebuild/Save Mark = " & swConfig.AddRebuildSaveMark)
    If swConfig.AddRebuildSaveMark = False Then
        swConfig.AddRebuildSaveMark = True
        bitmapName = configName + ".bmp"
        Debug.Print "      Resetting " & configName & "'s" & " Add Rebuild/Save Mark = " & swConfig.AddRebuildSaveMark
        bitmapPathName = "C:\Program Files\SolidWorks Corp\SolidWorks\samples\tutorial\api\" + bitmapName
        status = swApp.GetPreviewBitmapFile(fileName, configName, bitmapPathName)
        If status Then
             Debug.Print " " & configName & "'s " & "preview bitmap written to disk: " & bitmapPathName
        End If
    End If
Next

'Save the model to save each configuration's data with the model
'status = swModel.Save3(swSaveAsOptions_e.swSaveAsOptions_Silent, errors, warnings)

End Sub