Find Users Example (VB.NET)

This example shows how to find users in the vault.

NOTE: If using the .NET Framework 4.0 primary interop assembly provided with SolidWorks Enterprise PDM, see Using .NET Framework 4.0 in Stand-alone Applications.

'----------------------------------------------------------------------------
' Preconditions:
'  1. Start Microsoft Visual Studio 2010.
'     a. Click File > New > Project > Visual Basic > Windows Forms Application.
'     b. Type FindUser in Name.
'     c. Click Browse and navigate to the folder where to create the project.
'     d. Click OK. 
'     e. Click Show All Files in the Solution Explorer toolbar and expand 
'        Form1.vb in the Solution Explorer.
'     f. Replace the code in Form1.vb with this code.
'     g. To create the form, replace the code in Form1.Designer.vb with 
'        this code.
'  2. Add EPDM.Interop.epdm.dll as a reference (right-click the project
'     name in the Solution Explorer, click Add Reference, click 
'     Assemblies > Framework in the left-side panel, browse to the top folder of 
'     your SolidWorks Enterprise PDM installation, locate and click 
'     EPDM.Interop.epdm.dll, click Open, click Add, and click Close).
'  3. Right-click EPDM.Interop.epdm in References, click Properties, and set 
'     Embed Interop Types to False to handle methods that pass arrays of 
'     structures.
'  4. Click Debug > Start Debugging or press F5.
'
' Postconditions: 
'  1. Displays the Find Users dialog box.
'     a. Select a vault view.
'     b. In Full name contains, type a substring of the full name of a 
'        user that exists in the vault.
'     c. Click Find Users.
'        A message box confirms the substring typed in Postconditions
'        step 1b. 
'     d. Click OK.
'        Displays a Search for users dialog.
'     e. Click Find.
'        Displays a Search for users dialog with results.
'     f. Click the first row.
'     g. Click Select.
'        * Displays a message box with the updated user information.
'        * The selected user's phone and website information are updated.
'     h. Click OK.
'  2. Updates the Find Users dialog box with the full name and picture, if
'     it exists, of the last user found whose full name contains the substring 
'     typed in Postconditions step 1b. 
'  3. Close the Find Users dialog box.
'----------------------------------------------------------------------------
'Form1.vb

Imports System.IO
Imports System.Xml.Serialization
Imports System.Collections
Imports System.Collections.Generic
Imports System.Data
Imports System.Diagnostics
Imports System.Windows.Forms
Imports System.ComponentModel
Imports EPDM.Interop.epdm
 
Public Class Form1
    Dim vault1 As IEdmVault5 = New EdmVault5()
    Dim vault As IEdmVault8 = DirectCast(vault1, IEdmVault8)
    Dim Views As EdmViewInfo() = Nothing
    Public Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
 
        Try
            vault.GetVaultViews(Views, False)
            VaultsComboBox.Items.Clear()
            For Each View As EdmViewInfo In Views
                VaultsComboBox.Items.Add(View.mbsVaultName)
            Next
            If VaultsComboBox.Items.Count > 0 Then
                VaultsComboBox.Text = DirectCast(VaultsComboBox.Items(0), String)
            End If
        Catch ex As System.Runtime.InteropServices.COMException
            MessageBox.Show("HRESULT = 0x" + ex.ErrorCode.ToString("X") + " " + ex.Message)
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
 
    End Sub
 
    Private Sub FindUsers_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles FindUsers.Click
 
        Try
            Dim vault2 As IEdmVault7 = Nothing
            If vault1 Is Nothing Then
                vault1 = New EdmVault5()
            End If
            vault2 = DirectCast(vault1, IEdmVault7)
 
            If Not vault1.IsLoggedIn Then
                vault1.LoginAuto(VaultsComboBox.Text, Me.Handle.ToInt32())
            End If
 
            'Get the user search interface 
            Dim poFind As IEdmFindUser
            poFind = vault2.CreateUtility(EdmUtility.EdmUtil_FindUser)
 
            'Search for a user with specified text in the full user name 
            poFind.SetPropt(EdmFindUserProp.Edmfup_FullName, Me.TextBox1.Text)
            Dim val As String
            val = poFind.GetPropt(EdmFindUserProp.Edmfup_FullName)
            MessageBox.Show("Find users whose full names contain " & """" & val & """")
 
            poFind.ShowFindUI(Me.Handle.ToInt32(), True, "Search for users")
 
            Dim poResult As IEdmEnum
            poResult = poFind.Result
            Dim str As String = "Found " & poResult.Count.ToString & " users with full names containing, " & """" & Me.TextBox1.Text & """" & ":"
 
            Dim oImg As System.Drawing.Image
            Dim poUser As IEdmUser10
            Dim UserInfo As EdmUserDataEx = New EdmUserDataEx()
            UserInfo.mlEdmUserDataExFlags = EdmUserDataExFlag.Edmudex_All
 
            For Each element In poResult
                poUser = element
 
                'Get user's information
                poUser.GetUserDataEx(UserInfo)
 
                'Update user's information
                UserInfo.mbsPhone = "123456789"
                UserInfo.mbsWebSite1 = "http://www.solidworks.com"
                UserInfo.mbsWebSite2 = "https://www.facebook.com/solidworks"
                poUser.SetUserDataEx(UserInfo)
 
                str = str & vbLf & "Full name: " & UserInfo.mbsCompleteName & ", Phone: " & UserInfo.mbsPhone & ", WebSite1: " & UserInfo.mbsWebSite1 & ", Website2: " & UserInfo.mbsWebSite2
            Next
 
            MessageBox.Show(str)
 
            'Display the picture, if available, of the last user found 
            If Not UserInfo.mbsPicturePath = Nothing Then
                Me.TextBox2.Text = UserInfo.mbsCompleteName
                oImg = System.Drawing.Bitmap.FromFile(UserInfo.mbsPicturePath)
                Me.CreateGraphics().DrawImage(oImg, 40, 220)
            End If
 
        Catch ex As System.Runtime.InteropServices.COMException
            MessageBox.Show("HRESULT = 0x" + ex.ErrorCode.ToString("X") + " " + ex.Message)
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
 
    End Sub
 
End Class

Back to top

'Form1.Designer.vb

Back to top