Change Display Mode to Draft Quality Example (VBA)

This example shows how to change all of the display mode of all of the views in a drawing to draft quality.

'----------------------------------------------

'

' Preconditions: Drawing document is open and contains at least one view.

'

' Postconditions: All drawing views's display mode is changed to draft quality.

'

'-----------------------------------------------

Option Explicit

Public Enum swDisplayMode_e

    swWIREFRAME = 0

    swHIDDEN_GREYED = 1

    swHIDDEN = 2

    swSHADED = 3

    swFACETED_WIREFRAME = 4

    swFACETED_HIDDEN_GREYED = 5

    swFACETED_HIDDEN = 6

End Enum

Sub main()

    Dim swApp                   As SldWorks.SldWorks

    Dim swModel                 As SldWorks.ModelDoc2

    Dim swDraw                  As SldWorks.DrawingDoc

    Dim swSheet                 As SldWorks.Sheet

    Dim swView                  As SldWorks.View

    Dim bRet                    As Boolean

    Set swApp = Application.SldWorks

    Set swModel = swApp.ActiveDoc

    Set swDraw = swModel

    Set swSheet = swDraw.GetCurrentSheet

    Set swView = swDraw.GetFirstView

    Debug.Print "File = " & swModel.GetPathName

    Debug.Print "  " & swSheet.GetName

    While Not swView Is Nothing

        Debug.Print "    " & swView.Name & " [" & swView.GetDisplayMode2 & "]"

        If swSheet.GetName <> swView.Name Then

            ' Does not work on drawing sheet

            bRet = swView.SetDisplayMode3(False, swView.GetDisplayMode2, True, True): Debug.Assert bRet

        End If

        Set swView = swView.GetNextView

    Wend

End Sub