Get Dimension Tolerance Example (VBA)
This example shows how to get dimension tolerance minimum and maximum values.
'--------------------------------------------------------------------
' Preconditions:
' 1. Open install_dir\samples\tutorial\api\box.slddrw.
' 2. Open the Immediate window.
' 3. Zoom in on the diameter dimension and click it.
'
' Postconditions:
' 1. Changes Tolerance Type to Fit with tolerance.
' 2. Gets the minimum and maximum dimension tolerances for the
' selected dimension and whether the values are valid.
' 3. Gets the height and scale of the font for the dimension
' tolerances.
' 4. Examine the Immediate window and drawing sheet.
'
' NOTE: Because this drawing is used elsewhere, do not save changes.
'--------------------------------------------------------------------
Option Explicit
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swSelMgr As SldWorks.SelectionMgr
Dim swDisplayDimension As SldWorks.DisplayDimension
Dim swDimension As SldWorks.Dimension
Dim swDimensionTolerance As SldWorks.DimensionTolerance
Dim status As Boolean
Dim maxValue As Double
Dim minValue As Double
Dim maxValueValid As Long
Dim minValueValid As Long
Dim fontHeight As Double
Dim fontScale As Double
Sub main()
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swSelMgr = swModel.SelectionManager
'Get the selection
Set swDisplayDimension = swSelMgr.GetSelectedObject6(1, 0)
'If selection is not a dimension, then exit
If swSelMgr.GetSelectedObjectType3(1, -1) <> swSelectType_e.swSelDIMENSIONS Then Exit Sub
'Selection is a dimension, so get the dimension tolerance object
Set swDimension = swDisplayDimension.GetDimension2(0)
Set swDimensionTolerance = swDimension.Tolerance
'Set type of tolerance to Fit with tolerance
swDimensionTolerance.Type = swTolType_e.swTolFITWITHTOL
'Get dimension tolerance minimum and maximum values
'and whether values are valid
maxValueValid = swDimensionTolerance.GetMaxValue2(maxValue)
minValueValid = swDimensionTolerance.GetMinValue2(minValue)
Debug.Print ("Maximum dimension tolerance: " & maxValue & "; valid (0 = valid; 1 = not valid): " & maxValueValid)
Debug.Print ("Minimum dimension tolerance: " & minValue & "; valid (0 = valid; 1 = not valid): " & minValueValid)
'Get some dimension tolerance values
fontHeight = swDimensionTolerance.GetFontHeight
Debug.Print (" Height of font: " & fontHeight * 1000# & " mm")
fontScale = swDimensionTolerance.GetFontScale
Debug.Print (" Scale of font: " & fontScale)
End Sub