Favorite Search Example (VB.NET)

This example shows how to perform a favorite search.

NOTE: If using the primary interop assembly provided with SOLIDWORKS PDM Professional, see Using .NET Framework 4.0 in Stand-alone Applications.

'----------------------------------------------------------------------------
' Preconditions:
'  1. Start Microsoft Visual Studio.
'  2. Click File > New > Project > Visual Basic > Windows Forms Application.
'  3. Type FavoriteSearch in Name.
'  4. Click Browse to navigate to the folder where to create the project.
'  5. Click OK.
'  6. Click Show All Files in the Solution Explorer toolbar and expand 
'     Form1.vb in the Solution Explorer. 
'  7. Replace the code in Form1.vb with this code.
'  8. To create the form, replace the code in Form1.Designer.vb with this code.
'  9. Add EPDM.Interop.epdm.dll as a reference (right-click the project
'     name in the Solution Explorer, click Add Reference, click 
'     Assembly > Framework in the left-side panel, browse to the top folder of your 
'     SOLIDWORKS PDM Professional installation, locate and click 
'     EPDM.Interop.epdm.dll, click Open, click Add, and click Close).
' 10. Right-click EPDM.Interop.epdm in References, select Properties, and set 
'     Embed Interop Types to False to handle methods that pass arrays of 
'     structures.
' 11. Ensure that you know the name of a saved favorite search, and that search
'     finds at least one vault file whose extension (e.g., sldprt)
'     has a file data card (e.g. Quick Start Data Card) with a Description field.
' 12. Check out the vault file and add a description. Check it back in.
' 13. Use the Admin Tool to create a new column set for complete search results.
'     (Right-click on Admin Tool > vault_name > Columns > Search Result Columns and select New Column Set.
' 14. Click Add and select Description from the Variable dropdown
' 15. Save the new column set with name, MyFavoriteSearchResults.
' 16. Double-click Admin Tool > vault_name > Cards > Search Cards > Complete Search.
' 17. In the Card Properties panel, select the View and Preferred checkboxes next to MyFavoriteSearchResults.
' 18. Save and close the Card Editor dialog.
' 19. Click Debug > Start Debugging or press F5.
'
' Postconditions: 
'  1. Displays a dialog.
'  2. Select a vault.
'  3. Type in a favorite search name.
'  4. Click Perform Search.
'  5. Displays search results, including the custom search column, Description.
'  6. Close the dialog.
'---------------------------------------------------------------------------- 

'Form1.vb

Imports System.IO

Imports System.Xml.Serialization

Imports System.Collections

Imports System.Collections.Generic

Imports System.Data

Imports System.Diagnostics

Imports System.Windows.Forms

Imports System.ComponentModel

Imports EPDM.Interop.epdm

Public Class Form1

    Private vault1 As IEdmVault5 = Nothing

    Public Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        Try

            vault1 = New EdmVault5()

            Dim vault As IEdmVault8 = DirectCast(vault1, IEdmVault8)

            Dim Views As EdmViewInfo() = Nothing

            vault.GetVaultViews(Views, False)

            VaultsComboBox.Items.Clear()

            For Each View As EdmViewInfo In Views

                VaultsComboBox.Items.Add(View.mbsVaultName)

            Next

            If VaultsComboBox.Items.Count > 0 Then

                VaultsComboBox.Text = DirectCast(VaultsComboBox.Items(0), String)

            End If

        Catch ex As System.Runtime.InteropServices.COMException

            MessageBox.Show("HRESULT = 0x" + ex.ErrorCode.ToString("X") + " " + ex.Message)

        Catch ex As Exception

            MessageBox.Show(ex.Message)

        End Try

    End Sub

    Public Sub PerformSearch_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles PerformSearch.Click

        Try

            Dim vault2 As IEdmVault7 = Nothing

            If vault1 Is Nothing Then

                vault1 = New EdmVault5()

            End If

            vault2 = DirectCast(vault1, IEdmVault9)

            If Not vault1.IsLoggedIn Then

                vault1.LoginAuto(VaultsComboBox.Text, Me.Handle.ToInt32())

            End If

            Dim oSearch As IEdmSearch10 = vault1.CreateSearch()

            Dim oSearchResult As IEdmSearchResult6 = oSearch.GetFirstFavoriteResult(TextBox1.Text, True) 'get custom search result columns, if present

            Do

                'oSearchResult will have default values like path or ID, even if custom columns do not exist

                ListBox1.Items.Add("ID: " & oSearchResult.ID)

                ListBox1.Items.Add("Name: " & oSearchResult.Name)

                ListBox1.Items.Add("Path: " & oSearchResult.Path)

                ListBox1.Items.Add("Version: " & oSearchResult.Version)

                Dim oColsInfo() As EdmListCol = Nothing

                Dim oStrValues() As String = Nothing

                oSearchResult.GetCustomColumnsInfo(oColsInfo)

                oSearchResult.GetCustomColumnValues(oStrValues)

                If oColsInfo IsNot Nothing Then

                    For i As Integer = 0 To oColsInfo.Length - 1

                        ListBox1.Items.Add(oColsInfo(i).mbsCaption & ": " & oStrValues(i))

                    Next i

                End If

                oSearchResult = oSearch.GetNextResult() 'Get next result

            Loop Until oSearchResult Is Nothing

        Catch ex As System.Runtime.InteropServices.COMException

            MessageBox.Show("HRESULT = 0x" + ex.ErrorCode.ToString("X") + " " + ex.Message)

        Catch ex As Exception

            MessageBox.Show(ex.Message)

        End Try

    End Sub

End Class

Back to top

'Form1.Designer.vb

Back to top