生成 SOLIDWORKS 宏模板

SOLIDWORKS 宏模板是 SOLIDWORKS 宏，可当您在 SOLIDWORKS Task Scheduler 中将之排定为自定义任务时由您指定参数值。 SOLIDWORKS 宏模板是文本文件，通常包含 Visual Basic 代码、SOLIDWORKS API 调用及名称符记。 当您排定 SOLIDWORKS 宏模板作为自定义任务在 SOLIDWORKS Task Scheduler 中运行时，您指定参数值代替名称符记。

名称符记可以是文本字符串或数字。 它们格式化如下：

参数类型 名称符记的格式
字符串 $$$<名称符记>$$$
数量 ###<名称符记>###

SOLIDWORKS 宏模板必须具有 .swb 文件扩展名。

要生成宏模板：

  1. 使用 Windows 记事本、Microsoft WordPad、或其它文本编辑器打开新文本文件。
  2. 将 SOLIDWORKS 宏复制并粘贴到文本文件中。
    参阅 SOLIDWORKS API 和插件帮助主题了解有关 SOLIDWORKS 宏文件的信息。
  3. 键入名称符记取代您想指定其值的参数。 例如：
    原有代码： swApp.SetCurrentWorkingDirectory "c:\temp"
    修改过的代码： swApp.SetCurrentWorkingDirectory $$$TASK_WORKING_DIR$$$
  4. 以文件名扩展名 .swb 保存文本文件。
    在排定或运行之前创建 SOLIDWORKS 宏模板文件的备份，或者将 SOLIDWORKS 宏模板文件储存在任务工作目录以外的位置。 单击 视图 > 选项 > 任务选项 查看任务工作目录。 当使用 SOLIDWORKS 宏模板的任务运行时，系统创建宏模板的副本，并以您在排定任务时指定的参数值替换名称符记。 系统将文件保存在与原有 SOLIDWORKS 宏模板相同文件名称下的任务工作目录中。 如果原有 SOLIDWORKS 宏模板储存在任务工作目录中，系统会以新文件将之盖写。
    以下代码是 SOLIDWORKS 宏模板的范例。它将在文件夹中打开每个 SOLIDWORKS 工程图文档并将其保存为 DXF 文件。当您在 SOLIDWORKS Task Scheduler 中排定宏模板为自定义任务时，您指定参数替换名称符记：$$$TASK_SOURCE_DIR$$$和 $$$TASK_DESTINATION_DIR$$$。
    Dim swApp As Object
Dim swModel As Object
Dim ret As Boolean
Dim openError As Long
Dim openWarn As Long
Dim errorFilePath As String
Dim nErrors As Long
Dim nWarnings As Long
Dim destinationPath As String
Dim sourcePath As String
Dim modelTitle As String

Sub main()

    sourcePath = $$$TASK_SOURCE_DIR$$$
    destinationPath = $$$TASK_DESTINATION_DIR$$$
     
    errorFilePath = destinationPath + "\" + "swTaskScheduler.error"
    ErrorOut "Start logging any errors...", errorFilePath
    
    Set swApp = CreateObject("SldWorks.Application")
    swApp.SetCurrentWorkingDirectory destinationPath
    
    ' Determine type of document
    
    openWarn = 0
    
    Dim fileName As String
    fileName = Dir(sourcePath + "\*.SLDDRW")
    
    Do While fileName <> ""
        modelTitle = ""
        Set swModel = swApp.OpenDoc6(sourcePath + "\" + fileName, 3, 1, "", openError, openWarn)
        
        
        If (openWarn And 2) Then
            ErrorOut "File is read-only.", errorFilePath
            ret = False
        ElseIf (openWarn And 4) Then
            ErrorOut "File is locked by another user.", errorFilePath
            ret = False
        ElseIf (openWarn And 512) Then
            ErrorOut "File is view-only.", errorFilePath
            ret = False
        Else
            ret = True
        End If
        
        If Not swModel Is Nothing Then
            modelTitle = swModel.GetTitle()
            If ret = True Then
                    ' Strip off SOLIDWORKS drawing file extension (.slddrw)
                    ' and add DXF file extension (.dxf)
                    Dim sPathName As String
                    sPathName = swModel.GetPathName
                    sPathName = Left(sPathName, Len(sPathName) - 6)
                    sPathName = sPathName + "dxf"
                    sPathName = Replace(sPathName, sourcePath, destinationPath)
                    ' Save as file as DXF
                    bRet = swModel.SaveAs4(sPathName, swSaveAsCurrentVersion, swSaveAsOptions_Silent, nErrors, nWarnings)
            End If
            
            Set swModel = Nothing
            swApp.CloseDoc modelTitle
        End If

        
        fileName = Dir
    Loop
          
    ' Exit the SOLIDWORKS software
    swApp.ExitApp
    Set swApp = Nothing
    
End Sub

Function ErrorOut(errorString As String, errorFilePath As String)
    Open errorFilePath For Append As #5
    Print #5, errorString
    Close #5
End Function