Création d'un modèle de macro SolidWorks

Un modèle de macro SOLIDWORKS est une macro SOLIDWORKS qui vous permet de spécifier les valeurs des paramètres lorsque vous la planifiez en tant que tâche personnalisée dans le Planificateur de tâches SOLIDWORKS. Il s'agit d'un fichier texte contenant généralement un code Visual Basic, des appels SolidWorks API et des noms de jetons. Lorsque vous planifiez d'exécuter un modèle de macro SolidWorks en tant que tâche personnalisée dans le Planificateur de tâches SolidWorks, vous spécifiez les valeurs des paramètres qui doivent remplacer les noms de jetons.

Les noms de jetons peuvent être des chaînes de texte ou des valeurs numériques. Ils ont le format suivant:

Type de paramètre Format du nom de jeton
Chaîne $$$<nom_jeton>$$$
Nombre ###<nom_jeton>###

Un modèle de macro SolidWorks doit avoir l'extension .swb.

Pour créer un modèle de macro:

  1. Ouvrez un nouveau fichier texte à l'aide du Blocs-notes de Windows, de Microsoft WordPad ou d'un autre éditeur de texte.
  2. Copiez une macro SolidWorks et collez-la dans le fichier texte.
    Reportez-vous aux Rubriques d'aide de SolidWorks API et des compléments pour des informations sur les fichiers macro de SolidWorks.
  3. Saisissez les noms de jetons à la place des paramètres dont vous souhaitez spécifier les valeurs. Par exemple:
    Code original: swApp.SetCurrentWorkingDirectory "c:\temp"
    Code modifié: swApp.SetCurrentWorkingDirectory $$$TASK_WORKING_DIR$$$
  4. Enregistrez le fichier texte avec l'extension .swb.
    Avant de planifier et d'exécuter le fichier de modèle de macro SolidWorks, créez-en une copie de sauvegarde ou stockez-le à un autre emplacement que le dossier de travail des tâches. Cliquez sur Affichage > Options > Options des tâches pour afficher le dossier de travail des tâches. Lorsqu'une tâche utilisant un modèle de macro SolidWorks est exécutée, le système crée une copie du modèle de macro et remplace les noms des jetons par les valeurs de paramètres spécifiées lors de la planification de la tâche. Le fichier est sauvegardé dans le dossier de travail des tâches sous le même nom que celui du modèle de macro SolidWorks original. Si celui-ci est stocké dans le dossier de travail des tâches, le système le remplace par le nouveau fichier.
    Le code suivant est un exemple de modèle de macro SolidWorks. Il ouvre chaque document de mise en plan SOLIDWORKS dans un dossier et l'enregistre en tant que fichier DXF. Lorsque vous planifiez d'exécuter le modèle de macro en tant que tâche personnalisée dans le Planificateur de tâches SolidWorks, vous spécifiez les valeurs des paramètres qui doivent remplacer les noms de jetons : $$$TASK_SOURCE_DIR$$$ et $$$TASK_DESTINATION_DIR$$$.
    Dim swApp As Object
Dim swModel As Object
Dim ret As Boolean
Dim openError As Long
Dim openWarn As Long
Dim errorFilePath As String
Dim nErrors As Long
Dim nWarnings As Long
Dim destinationPath As String
Dim sourcePath As String
Dim modelTitle As String

Sub main()

    sourcePath = $$$TASK_SOURCE_DIR$$$
    destinationPath = $$$TASK_DESTINATION_DIR$$$
     
    errorFilePath = destinationPath + "\" + "swTaskScheduler.error"
    ErrorOut "Start logging any errors...", errorFilePath
    
    Set swApp = CreateObject("SldWorks.Application")
    swApp.SetCurrentWorkingDirectory destinationPath
    
    ' Determine type of document
    
    openWarn = 0
    
    Dim fileName As String
    fileName = Dir(sourcePath + "\*.SLDDRW")
    
    Do While fileName <> ""
        modelTitle = ""
        Set swModel = swApp.OpenDoc6(sourcePath + "\" + fileName, 3, 1, "", openError, openWarn)
        
        
        If (openWarn And 2) Then
            ErrorOut "File is read-only.", errorFilePath
            ret = False
        ElseIf (openWarn And 4) Then
            ErrorOut "File is locked by another user.", errorFilePath
            ret = False
        ElseIf (openWarn And 512) Then
            ErrorOut "File is view-only.", errorFilePath
            ret = False
        Else
            ret = True
        End If
        
        If Not swModel Is Nothing Then
            modelTitle = swModel.GetTitle()
            If ret = True Then
                    ' Strip off SOLIDWORKS drawing file extension (.slddrw)
                    ' and add DXF file extension (.dxf)
                    Dim sPathName As String
                    sPathName = swModel.GetPathName
                    sPathName = Left(sPathName, Len(sPathName) - 6)
                    sPathName = sPathName + "dxf"
                    sPathName = Replace(sPathName, sourcePath, destinationPath)
                    ' Save as file as DXF
                    bRet = swModel.SaveAs4(sPathName, swSaveAsCurrentVersion, swSaveAsOptions_Silent, nErrors, nWarnings)
            End If
            
            Set swModel = Nothing
            swApp.CloseDoc modelTitle
        End If

        
        fileName = Dir
    Loop
          
    ' Exit the SOLIDWORKS software
    swApp.ExitApp
    Set swApp = Nothing
    
End Sub

Function ErrorOut(errorString As String, errorFilePath As String)
    Open errorFilePath For Append As #5
    Print #5, errorString
    Close #5
End Function