SOLIDWORKS マクロ テンプレートの作成

SOLIDWORKS マクロ テンプレートとは、SOLIDWORKS タスク スケジューラでユーザー定義タスクとしてスケジュールしたときにパラメータ値を指定できる SOLIDWORKS のマクロです。 SOLIDWORKS マクロ テンプレートは、通常、Visual Basic のコード、SOLIDWORKS API の呼び出しやトークン名などが含まれているテキスト ファイルです。 SOLIDWORKS タスク スケジューラで SOLIDWORKS マクロ テンプレートをユーザー定義タスクとして実行するようスケジュールする場合、トークン名の代わりにパラメータ値を指定します。

トークン名には、テキスト ストリングス、または数値のどちらでも使用できます。 これらは次のようにフォーマット化されています：

パラメータのタイプ トークン名のフォーマット
文字列 $$$<トークン_名>$$$
番号 ###<トークン_名>###

SOLIDWORKS マクロ テンプレートのファイル名拡張子は .swb である必要があります。

マクロテンプレートを作成するには：

  1. ウィンドウズのメモ帳（Windows Notepad）、Microsoft WordPad、またその他のテキストエディターを使用して新しいテキスト ファイルを開きます。
  2. SOLIDWORKS のマクロをコピーしてテキスト ファイルに貼り付けます。
    SOLIDWORKS のマクロ ファイルの詳細については、SOLIDWORKS API /アドインヘルプ　トピック（SOLIDWORKS API and Add-Ins Help Topics）を参照してください。
  3. 指定する値をパラメータの変わりにトークン名で入力します。 例:
    元のコード： swApp.SetCurrentWorkingDirectory "c:\temp"
    変更したコード swApp.SetCurrentWorkingDirectory $$$TASK_WORKING_DIR$$$
  4. .swb というファイル名拡張子とともにテキスト ファイルを保存します。
    スケジュールしたり、実行したりする前に SOLIDWORKS マクロ テンプレート ファイルのバックアップ コピーを作成するか、タスク作業ディレクトリとは異なる場所に SOLIDWORKS マクロ テンプレート ファイルを保存します。 表示 > オプション > タスク オプション をクリックするとタスクの作業ディレクトリを参照できます。 SOLIDWORKS マクロ テンプレートを使用したタスクを実行すると、システムによりマクロ テンプレートのコピーが作成され、タスクをスケジュールしたときに指定したパラメータ値でトークン名が置き換えられます。 システムによってファイルは、タスク作業ディレクトリに元の SOLIDWORKS マクロ テンプレートと同じファイル名で保存されます。 元の SOLIDWORKS マクロ テンプレートがタスク作業ディレクトリに保存されている場合、新規ファイルで上書きされます。
    次のコードは SOLIDWORKS マクロ テンプレートの例です。このコードでは、フォルダ内の SOLIDWORKS の各図面ドキュメントが開かれ、DXF ファイルとして保存されます。SOLIDWORKS タスク スケジューラで マクロ テンプレートをユーザー定義タスクとしてスケジュールする場合、トークン名の代わりにパラメータ値を指定します: $$$TASK_SOURCE_DIR$$$と $$$TASK_DESTINATION_DIR$$$ 
    Dim swApp As Object
Dim swModel As Object
Dim ret As Boolean
Dim openError As Long
Dim openWarn As Long
Dim errorFilePath As String
Dim nErrors As Long
Dim nWarnings As Long
Dim destinationPath As String
Dim sourcePath As String
Dim modelTitle As String

Sub main()

    sourcePath = $$$TASK_SOURCE_DIR$$$
    destinationPath = $$$TASK_DESTINATION_DIR$$$
     
    errorFilePath = destinationPath + "\" + "swTaskScheduler.error"
    ErrorOut "Start logging any errors...", errorFilePath
    
    Set swApp = CreateObject("SldWorks.Application")
    swApp.SetCurrentWorkingDirectory destinationPath
    
    ' Determine type of document
    
    openWarn = 0
    
    Dim fileName As String
    fileName = Dir(sourcePath + "\*.SLDDRW")
    
    Do While fileName <> ""
        modelTitle = ""
        Set swModel = swApp.OpenDoc6(sourcePath + "\" + fileName, 3, 1, "", openError, openWarn)
        
        
        If (openWarn And 2) Then
            ErrorOut "File is read-only.", errorFilePath
            ret = False
        ElseIf (openWarn And 4) Then
            ErrorOut "File is locked by another user.", errorFilePath
            ret = False
        ElseIf (openWarn And 512) Then
            ErrorOut "File is view-only.", errorFilePath
            ret = False
        Else
            ret = True
        End If
        
        If Not swModel Is Nothing Then
            modelTitle = swModel.GetTitle()
            If ret = True Then
                    ' Strip off SOLIDWORKS drawing file extension (.slddrw)
                    ' and add DXF file extension (.dxf)
                    Dim sPathName As String
                    sPathName = swModel.GetPathName
                    sPathName = Left(sPathName, Len(sPathName) - 6)
                    sPathName = sPathName + "dxf"
                    sPathName = Replace(sPathName, sourcePath, destinationPath)
                    ' Save as file as DXF
                    bRet = swModel.SaveAs4(sPathName, swSaveAsCurrentVersion, swSaveAsOptions_Silent, nErrors, nWarnings)
            End If
            
            Set swModel = Nothing
            swApp.CloseDoc modelTitle
        End If

        
        fileName = Dir
    Loop
          
    ' Exit the SOLIDWORKS software
    swApp.ExitApp
    Set swApp = Nothing
    
End Sub

Function ErrorOut(errorString As String, errorFilePath As String)
    Open errorFilePath For Append As #5
    Print #5, errorString
    Close #5
End Function