Tworzenie szablonu makr SOLIDWORKS

Szablon makr SOLIDWORKS to makro SOLIDWORKS, które pozwala określać wartości parametrów, gdy szablon ten zostanie zaplanowany do wykonania jako dostosowane zadanie w Harmonogramie zadań SOLIDWORKS. Szablon makr SOLIDWORKS jest plikiem tekstowym, który standardowo zawiera kod Visual Basic, odwołania do interfejsu API SOLIDWORKS oraz nazwy tokenów. Przy planowaniu uruchomienia szablonu makr SOLIDWORKS jako dostosowanego zadania w Harmonogramie zadań SOLIDWORKS należy określić wartości parametrów, które zastąpią nazwy tokenów.

Nazwy tokenów mogą być ciągami tekstowymi lub numerycznymi. Mają one następujący format:

Typ parametru Format nazwy tokena
Ciąg $$$<nazwa_tokena>$$$
Numer ###<nazwa_tokena>###

Plik szablonu makr SOLIDWORKS musi mieć rozszerzenie .swb.

Aby utworzyć szablon makr, należy:

  1. Otworzyć nowy plik tekstowy przy użyciu aplikacji Notatnik Windows, Microsoft WordPad lub innego edytora tekstu.
  2. Skopiować i wkleić makro SOLIDWORKS do tego pliku tekstowego.
    Aby uzyskać informacje o plikach makr SOLIDWORKS, należy zapoznać się z częścią Tematy Pomocy dla SOLIDWORKS API i dodatków.
  3. Wpisać nazwy tokenów w miejsce parametrów, których wartości chcemy określić. Na przykład:
    Pierwotny kod: swApp.SetCurrentWorkingDirectory "c:\temp"
    Zmodyfikowany kod: swApp.SetCurrentWorkingDirectory $$$TASK_WORKING_DIR$$$
  4. Zapisać plik tekstowy z rozszerzeniem .swb.
    Przed zaplanowaniem i uruchomieniem pliku szablonu makr SOLIDWORKS należy utworzyć jego kopię zapasową lub umieścić plik szablonu makr SOLIDWORKS w lokalizacji innej niż katalog roboczy zadań. Kliknąć Widok > Opcje > Opcje zadań , aby wyświetlić katalog roboczy zadań. Gdy zadanie wykorzystujące szablon makr SOLIDWORKS zostanie uruchomione, system utworzy kopię szablonu makr i zastąpi nazwy tokenów wartościami parametrów, które określiliśmy podczas planowania zadania. System zapisze ten plik w katalogu roboczym zadań pod tą samą nazwą co pierwotny szablon makr SOLIDWORKS. Jeżeli pierwotny szablon makr SOLIDWORKS jest zapisany w katalogu roboczym zadań, wówczas system zastąpi go nowym plikiem.
    Poniższy kod stanowi przykład szablonu makr SOLIDWORKS. Otwiera każdy dokument rysunku SOLIDWORKS w folderze i zapisuje go jako plik DXF. Przy planowaniu uruchomienia szablonu makr jako dostosowanego zadania w Harmonogramie zadań SOLIDWORKS należy określić parametry, które zastąpią nazwy tokenów: $$$TASK_SOURCE_DIR$$$ i $$$TASK_DESTINATION_DIR$$$.
    Dim swApp As Object
Dim swModel As Object
Dim ret As Boolean
Dim openError As Long
Dim openWarn As Long
Dim errorFilePath As String
Dim nErrors As Long
Dim nWarnings As Long
Dim destinationPath As String
Dim sourcePath As String
Dim modelTitle As String

Sub main()

    sourcePath = $$$TASK_SOURCE_DIR$$$
    destinationPath = $$$TASK_DESTINATION_DIR$$$
     
    errorFilePath = destinationPath + "\" + "swTaskScheduler.error"
    ErrorOut "Start logging any errors...", errorFilePath
    
    Set swApp = CreateObject("SldWorks.Application")
    swApp.SetCurrentWorkingDirectory destinationPath
    
    ' Determine type of document
    
    openWarn = 0
    
    Dim fileName As String
    fileName = Dir(sourcePath + "\*.SLDDRW")
    
    Do While fileName <> ""
        modelTitle = ""
        Set swModel = swApp.OpenDoc6(sourcePath + "\" + fileName, 3, 1, "", openError, openWarn)
        
        
        If (openWarn And 2) Then
            ErrorOut "File is read-only.", errorFilePath
            ret = False
        ElseIf (openWarn And 4) Then
            ErrorOut "File is locked by another user.", errorFilePath
            ret = False
        ElseIf (openWarn And 512) Then
            ErrorOut "File is view-only.", errorFilePath
            ret = False
        Else
            ret = True
        End If
        
        If Not swModel Is Nothing Then
            modelTitle = swModel.GetTitle()
            If ret = True Then
                    ' Strip off SOLIDWORKS drawing file extension (.slddrw)
                    ' and add DXF file extension (.dxf)
                    Dim sPathName As String
                    sPathName = swModel.GetPathName
                    sPathName = Left(sPathName, Len(sPathName) - 6)
                    sPathName = sPathName + "dxf"
                    sPathName = Replace(sPathName, sourcePath, destinationPath)
                    ' Save as file as DXF
                    bRet = swModel.SaveAs4(sPathName, swSaveAsCurrentVersion, swSaveAsOptions_Silent, nErrors, nWarnings)
            End If
            
            Set swModel = Nothing
            swApp.CloseDoc modelTitle
        End If

        
        fileName = Dir
    Loop
          
    ' Exit the SOLIDWORKS software
    swApp.ExitApp
    Set swApp = Nothing
    
End Sub

Function ErrorOut(errorString As String, errorFilePath As String)
    Open errorFilePath For Append As #5
    Print #5, errorString
    Close #5
End Function