SOLIDWORKS Makro Şablonu Oluşturma

SOLIDWORKS makro şablonu, SOLIDWORKS Görev Zamanlayıcı'da özel bir görev olarak zamanlarken parametre değerlerini belirlemenizi sağlayan bir SOLIDWORKS makrosudur. SOLIDWORKS makro şablonu genellikle Visual Basic kodu, SOLIDWORKS API çağrıları ve belirteç adları içeren bir metin dosyasıdır. SOLIDWORKS makro şablonunu SOLIDWORKS Görev Zamanlayıcı'da özel bir görev olarak çalışmak üzere zamanlayarak, belirteç adlarının yerine kullanılmak üzere parametre değerleri belirleyebilirsiniz.

Simge adları, metin dizeleri veya rakamlardan oluşabilir. Aşağıdaki gibi biçimlendirilir:

Parametre Tipi Simge Adı Formatı
Dize $$$<token_name>$$$
Sayı ###<token_name>###

SOLIDWORKS makro şablonunun .swb dosya adı uzantısına sahip olması gerekir.

Makro şablonu oluşturmak için:

  1. Windows Notepad, Microsoft WordPad veya başka bir metin düzenleyici kullanarak yeni bir metin dosyası açın.
  2. SOLIDWORKS makrosunu metin dosyasına kopyalayın ve yapıştırın.
    SOLIDWORKS makro dosyaları hakkında bilgi için bkz. SOLIDWORKS API ve Eklentiler Yardım Konuları.
  3. Değerlerini belirlemek istediğiniz parametrelerin yerine simge adlarını yazın. Örneğin:
    Orijinal kod: swApp.SetCurrentWorkingDirectory "c:\temp"
    Değiştirilmiş kod: swApp.SetCurrentWorkingDirectory $$$TASK_WORKING_DIR$$$
  4. Metin dosyasını .swb dosya adı uzantısıyla kaydedin.
    SOLIDWORKS makro şablonunu zamanlamadan ve çalıştırmadan önce yedek kopyasını oluşturun veya SOLIDWORKS makro şablon dosyasını görev çalışma dizini dışında bir konumda saklayın. Görev çalışma dizinini görüntülemek için Görünüm > Seçenekler > Görev Seçenekleri öğesine tıklayın. SOLIDWORKS makro şablonu kullanan bir görev çalıştığında, sistem makro şablonun kopyasını oluşturur ve belirteç adlarını görevi zamanlarken belirlediğiniz parametre değerleriyle değiştirir. Sistem dosyayı, orijinal SOLIDWORKS makro şablonuyla aynı adla görev çalışma dizinine kaydeder. Orijinal SOLIDWORKS makro şablonu görev çalışma dizininde saklanıyorsa sistem yeni dosyayı bu şablonun üzerine yazar.
    Aşağıdaki kod, SOLIDWORKS makro şablonu örneğidir. Her bir SOLIDWORKS teknik resim belgesini bir klasörde açar ve bunu DXF dosyası olarak kaydeder. Makro şablonu SOLIDWORKS Görev Zamanlayıcı'da özel bir görev olarak zamanlayarak belirteç adlarının yerini alacak parametreleri belirleyebilirsiniz: $$$TASK_SOURCE_DIR$$$ ve $$$TASK_DESTINATION_DIR$$$.
    Dim swApp As Object
Dim swModel As Object
Dim ret As Boolean
Dim openError As Long
Dim openWarn As Long
Dim errorFilePath As String
Dim nErrors As Long
Dim nWarnings As Long
Dim destinationPath As String
Dim sourcePath As String
Dim modelTitle As String

Sub main()

    sourcePath = $$$TASK_SOURCE_DIR$$$
    destinationPath = $$$TASK_DESTINATION_DIR$$$
     
    errorFilePath = destinationPath + "\" + "swTaskScheduler.error"
    ErrorOut "Start logging any errors...", errorFilePath
    
    Set swApp = CreateObject("SldWorks.Application")
    swApp.SetCurrentWorkingDirectory destinationPath
    
    ' Determine type of document
    
    openWarn = 0
    
    Dim fileName As String
    fileName = Dir(sourcePath + "\*.SLDDRW")
    
    Do While fileName <> ""
        modelTitle = ""
        Set swModel = swApp.OpenDoc6(sourcePath + "\" + fileName, 3, 1, "", openError, openWarn)
        
        
        If (openWarn And 2) Then
            ErrorOut "File is read-only.", errorFilePath
            ret = False
        ElseIf (openWarn And 4) Then
            ErrorOut "File is locked by another user.", errorFilePath
            ret = False
        ElseIf (openWarn And 512) Then
            ErrorOut "File is view-only.", errorFilePath
            ret = False
        Else
            ret = True
        End If
        
        If Not swModel Is Nothing Then
            modelTitle = swModel.GetTitle()
            If ret = True Then
                    ' Strip off SOLIDWORKS drawing file extension (.slddrw)
                    ' and add DXF file extension (.dxf)
                    Dim sPathName As String
                    sPathName = swModel.GetPathName
                    sPathName = Left(sPathName, Len(sPathName) - 6)
                    sPathName = sPathName + "dxf"
                    sPathName = Replace(sPathName, sourcePath, destinationPath)
                    ' Save as file as DXF
                    bRet = swModel.SaveAs4(sPathName, swSaveAsCurrentVersion, swSaveAsOptions_Silent, nErrors, nWarnings)
            End If
            
            Set swModel = Nothing
            swApp.CloseDoc modelTitle
        End If

        
        fileName = Dir
    Loop
          
    ' Exit the SOLIDWORKS software
    swApp.ExitApp
    Set swApp = Nothing
    
End Sub

Function ErrorOut(errorString As String, errorFilePath As String)
    Open errorFilePath For Append As #5
    Print #5, errorString
    Close #5
End Function