Mirror Components Example (VBA)

This example shows how to mirror components in an assembly.

'----------------------------------------------------------------------------
' Preconditions: Open public_documents\samples\tutorial\advdrawings\98food processor.sldasm.
'
' Postconditions:
' 1. Inserts reference plane PLANE4.
' 2. Creates feature MirrorComponent1 that mirrors six assembly
'    components.
' 3. Saves the mirror components to files with file name suffix _TestMirror to
'    public_documents\samples\tutorial\advdrawings.
' 4. Examine public_documents\samples\tutorial\advdrawings, the FeatureManager design
'    tree, and the graphics area.
'
' NOTE: Because the assembly is used elsewhere, do not save changes.
'---------------------------------------------------------------------------

Option Explicit

Sub main()
    Dim swApp As SldWorks.SldWorks
    Set swApp = Application.SldWorks   

    Dim swModel As SldWorks.ModelDoc2
    Set swModel = swApp.ActiveDoc   

    Dim boolstatus As Boolean
    boolstatus = swModel.Extension.SelectByID2("", "FACE", 0.104250921669188, -2.36987012272039E-04, -5.97199999999418E-02, True, 0, Nothing, 0)
    Dim myRefPlane As SldWorks.RefPlane
    Set myRefPlane = swModel.FeatureManager.InsertRefPlane(8, 0.01, 0, 0, 0, 0)   

    Dim swAssem As SldWorks.AssemblyDoc
    Set swAssem = swModel
   

    Dim compsToInstance As Object
    Set compsToInstance = Nothing   

    Dim filenames As Object
    Set filenames = Nothing   

    Dim location As String
    location = ""   

    Dim nameModifierType As swMirrorComponentNameModifier_e
    nameModifierType = swMirrorComponentName_Suffix
    Dim nameModifier As String
    nameModifier = "_TestMirror"   

    Dim mirrorPlane As SldWorks.Feature
    Set mirrorPlane = swAssem.FeatureByName("PLANE4")   

    Dim compsToMirror(0 To 5) As Object
    Set compsToMirror(0) = swAssem.GetComponentByName("gear- caddy-1")
    Set compsToMirror(1) = swAssem.GetComponentByName("middle-gear-1")
    Set compsToMirror(2) = swAssem.GetComponentByName("shaft gear-1")
    Set compsToMirror(3) = swAssem.GetComponentByName("middle-gear plate-1")
    Set compsToMirror(4) = swAssem.GetComponentByName("base plate-1")
    Set compsToMirror(5) = swAssem.GetComponentByName("shaft gear insert-1")   

    Dim orientations As Object
    Set orientations = Nothing   

    Dim orientAboutCoM As Boolean
    orientAboutCoM = True   

    Dim createDerivedConfigs As Boolean
    createDerivedConfigs = False   

    Dim importOptions As Long
    importOptions = swMirrorPartOptions_ImportSolids

    Dim breakLinks As Boolean
    breakLinks = False
    Dim preserveZAxis As Boolean
    preserveZAxis = True   

    Dim vResult As Variant
    vResult = swAssem.MirrorComponents3(mirrorPlane, compsToInstance, orientations, orientAboutCoM, (compsToMirror), createDerivedConfigs, filenames, nameModifierType, nameModifier, location, importOptions, breakLinks, preserveZAxis, True)
   

End Sub